home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
TPUG - Toronto PET Users Group
/
TPUG Users Group CD
/
TPUG Users Group CD.iso
/
C64
/
T-TPUG Old Monthly Disks
/
(c)tt.d64
/
time adventure.c
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2007-02-04
|
4KB
|
140 lines
11 OPEN1,8,2,"0:TIM VEN1,S,R":GOSUB97
12 OPEN1,8,2,"0:TIM VEN2,S,R":GOSUB95
13 OPEN1,8,2,"0:TIM VEN3,S,R":GOSUB95
14 OPEN1,8,2,"0:TIM VEN4,S,R":GOSUB95
15 OPEN1,8,2,"0:TIM VEN5,S,R":GOSUB95
16 OPEN1,8,2,"0:TIM VEN6,S,R":GOSUB95
17 OPEN1,8,2,"0:TIM VEN7,S,R":GOSUB95
18 OPEN1,8,2,"0:TIM VEN8,S,R":GOSUB95
19 PRINT"**** CONGRATULATIONS ****"
20 PRINT"YOU HAVE WON TIME VENTURE!!!"
23 PRINT"[147]":END
95 PRINT"CONGRATULATIONS YOU HAVE JUST LEFT THE"N$"AREA"
96 PRINT"BUT YOUR NOT DONE YET!!"
97 CLR:INPUT#1,N$
98 PRINT" YOU HAVE JUST ENTERED A";N$
99 INPUT#1,A1,B1,C1,RT,BE,TR,GB,RC,TT:RESTORE
100 DIMR$(A1,B1,C1),R%(6),T$(RT),M%(5),M$(5),F$(BE),G$(BE),C$(TR),B$(GB)
110 DIMB%(GB),Z$(RC),S$(SP),W$(SP)
280 FORL=0TOA1:FORJ=0TOB1:FORK=0TOCQ:INPUT#1,R$(L,J,K):NEXTK,J,L
300 FORJ=0TORT:INPUT#1,T$(J):NEXTJ
330 FORX=0TO5:READM$(X):NEXTX
331 M%(1)=(A1+1)*(B1+1):M%(0)=-M%(1)
332 M%(2)=A1+1:M%(3)=-M%(2)
333 M%(4)=1:M%(5)=-1
370 FORX=0TOBE:INPUT#1,F$(X):INPUT#1,G$(X):NEXTX
400 FORX=0TOTR:INPUT#1,C$(X):NEXTX
412 FORJ=0TORC:INPUT#1,Z$(J):NEXTJ
420 FORX=0TOGB:INPUT#1,B$(X):NEXTX
450 X=RND(-TI):FORX=0TO3:INPUT#1,S$(X):W$(X)="X":READS$:S$(X)=S$(X)+S$
460 FORJ=1TOX+2:Z$=CHR$(RND(1)*15+65):W$(X)=W$(X)+Z$:NEXTJ,X
470 CLOSE1:V=20
480 IFV<15THENV=15:PRINT"VITALITY RESTORED TO";V
490 J=0:K=0:L=0
500 IFL+1<C1THEN509
501 IFR=1THEN1440
502 R$="YOU ARE NEXT TO A TIME MACHINE SIGN SAYS '500 COINS'"
503 D$=" "
504 R$=R$+" GO WEST TO ENTER TIME MACHINE"
509 D$=LEFT$(R$,1):T=VAL(MID$(R$,2,1)):H$=T$(T)
510 R$="YOU ARE IN A "+MID$(R$,3)+" "+H$
520 PRINTR$:A=J*(A1+1)+K+L*((A1+1)*(B1+1))
530 R=-1:D=ASC(D$):D1=1:FORX=0TO5:IF(DANDD1)>0THENGOSUB1320
540 D1=D1*2:NEXTX:A1=A+32:IFR=0ANDR%(0)+M2=0THENPRINT"==DEAD END=="
545 FORX=0TORC:IFASC(Z$(X))=A1THENPRINTMID$(Z$(X),2)
546 NEXTX
550 FORX=0TOSP:IFASC(S$(X))=A1GOTO570
560 NEXTX:GOTO580
570 IFX<>3ORB%(1)=1THENPRINTMID$(S$(X),2);" SPELL WORD IS ";W$(X);"[146]'"
580 B1=0:FORX=0TOGB:IFASC(B$(X))=A1GOTO600
590 NEXTX:GOTO620
600 B$=MID$(B$(X),2):B1=1:B2=X
610 PRINT"THERE IS A ";B$;" HERE."
620 C1=0:FORX=0TOTR:IFASC(C$(X))=A1GOTO640
630 NEXTX:GOTO660
640 C1=VAL(MID$(C$(X),2,1))*100:C$=MID$(C$(X),3):PRINT"THERE ARE";C1;C$;" HERE"
650 C2=X
660 G$="":FORX=0TOBE:IFASC(F$(X))=A1GOTO680
670 NEXTX:GOTO720
680 G$=G$(X):PRINT"A ";MID$(F$(X),4);" ";G$;" BARS YOUR WAY!"
690 G1=VAL(MID$(F$(X),2,1)):G2=VAL(MID$(F$(X),3,1))*100:IFG2=0THENG2=1E9
700 G3=(X+1)*INT(X/3+1):G5=X
720 INPUT"MOVE";Y$
727 Z$=LEFT$(Y$,1)
730 J1=0:K1=0:L1=0
740 IFZ$="D"THENL1=1
750 IFZ$="U"THENL1=-1
760 IFZ$="N"THENJ1=1
770 IFZ$="S"THENJ1=-1
780 IFZ$="E"THENK1=1
790 IFZ$="W"THENK1=-1
800 M1=K1+(A1+1)*J1+((A1+1)*(B1+1))*L1:IFM1=0GOTO880
810 FORX=0TOR:IFM1=R%(X)GOTO830
820 NEXTX:PRINT"YOU CAN'T GO THAT WAY":GOTO720
830 IFG$<>""ANDM1+M2<>0THENPRINT"THE ";G$;" WON'T LET YOU BY!":GOTO720
840 M9=M9+1:M2=M1:J=J+J1:K=K+K1:L=L+L1
870 R$=R$(J,K,L):GOTO500
880 IFZ$="F"ORZ$="B"GOTO1120
890 IFZ$="T"GOTO1030
900 IFZ$="X"GOTO930
910 PRINT"N[146]ORTH S[146]OUTH E[146]AST W[146]EST U[146]P D[146]OWN F[146]IGHT B[146]ARGAIN T[146]AKE"
920 GOTO720
930 FORX=0TOSP:IFY$=W$(X)GOTO960
940 NEXTX
950 PRINT"?? NOTHING HAPPENS ??":GOTO720
960 IFL=3ANDX=2GOTO950
970 IFX=0THENJ=3:K=3:M2=3:GOTO850
980 IFX>0ANDX<3ANDG$=""GOTO950
990 S$(X)="[255]":W$(X)="[255]"
1000 IFX=1THENPRINT"THE ";G$;" FALLS ASLEEP.":G$="":GOTO720
1010 IFX=2THENPRINT"THE ";G$;" VANISHES!":G$="":F$(G5)="[255]":GOTO720
1020 V=20:PRINT"VITALITY RESTORED TO";V:GOTO720
1030 IFB1+C1=0THENPRINT"?? NOTHING HERE ??":GOTO720
1040 IFG$<>""THENPRINT"THE ";G$;" WON'T LET YOU HAVE IT!":GOTO720
1050 IFB1=0GOTO1110
1060 B%(B2)=1:B1=0:B$(B2)="[255]"+MID$(B$(B2),2)
1070 PRINT"YOU NOW HAVE:";:Z=C$(L*2)=C$(L*2+1):FORX=0TOGB:IFB%(X)=0GOTO1090
1080 PRINT:PRINT"..";MID$(B$(X),2);
1090 NEXT X:IFZTHENPRINT:PRINT"** ALL TREASURE";:IFT9<8THENPRINT" IN LEVEL";L+1;
1100 PRINT:PRINT"..";V1;" COINS.":GOTO720
1110 E=E+1:V1=V1+C1:C1=0:C$(C2)="[255]":T9=T9+1:GOTO1070
1120 IFG$=""THENPRINT"?? NOBODY HERE ??":GOTO720
1130 IFZ$="B"GOTO1210
1140 PRINT"THE ";G$;" ";:G4=5:IFG3<=5THENG4=G3:GOTO1170
1150 PRINT"IS WOUNDED";
1160 GOTO1180
1170 PRINT"IS OVERCOME";:G$="":F$(G5)="[255]":E=E+1
1180 V=V-G4*10/(10+E+8*B%(3)+5*B%(2)):IFV<=0THENPRINT"-BUT YOU'RE KILLED!":GOTO1480
1190 PRINT":YOUR VITALITY IS REDUCED TO";INT(V)
1200 G3=G3-G4:GOTO720
1210 IFG2>V1GOTO1240
1220 PRINT"THE ";G$;" WANTS";G2;"COINS: OK";:INPUTZ$:IFASC(Z$)=78GOTO1240
1230 V1=V1-G2:GOTO1290
1240 IFG1>3GOTO1310
1250 IFB%(G1)=0GOTO1310
1260 PRINT"THE ";G$;" WILL TAKE THE ";MID$(B$(G1),2);": OK";:INPUTZ$
1270 IFASC(Z$)=78GOTO1310
1280 B%(G1)=0
1290 PRINT"IT'S A DEAL! THE ";G$;" IS GONE."
1300 E=E+1:G$="":F$(G5)="[255]":GOTO1070
1310 PRINT"NO DEAL...":GOTO720
1320 R=R+1:M=M%(X):R%(R)=M:M$=M$(X)
1330 X$="YOU MAY GO":IFL<0GOTO1430
1340 A1=A+M:IFA1<0GOTO1430
1350 L1=INT(A1/16):A1=A1-L1*16:J1=INT(A1/4):K1=A1-J1*4
1360 T1=VAL(MID$(R$(J1,K1,L1),2,1))
1370 IFT=T1THENX$="THE "+H$+" CONTINUES":GOTO1430
1380 IFT<>3ANDT1<>3GOTO1410
1390 X$="A DOORWAY OPENS":IFABS(M)>15THENX$="A STAIRWAY LEADS"
1400 GOTO1430
1410 IFT=0ORT1=0THENX$="A TUNNEL GOES":GOTO1430
1420 X$="A PASSAGE LEADS"
1430 PRINTX$;" ";M$:RETURN
1440 IFV1<>TT*100THENR=0;:GOTO950
1480 RETURN
2000 DATAUP,DOWN,NORTH,SOUTH,EAST,WEST
2001 DATAA VOICE SAYS 'SLEEP
2002 DATAA POSTER READS 'TRAVEL
2003 DATAA DIPLOMA READS 'HEALING
2004 DATAA NOTE SAYS 'VANISHING